/*
Helper Menu Addon By diEfoRyoU 
Tarih: 20.03.2006 
Site: www.IRCForumlari.Net 
Server: IRc.IRCforumlari.Net 
Kanal: #LoCk 
*/
on me:*:rawmode:#help:{
  if $1 == +v {
    set %hmenu.nick $2
    msg # Merhaba %hmenu.nick $+ , Size nasıl yardımcı olabilirim?
    set %hmenu.pause on
  }
  elseif $1 == -v {
    msg # Sorununuz çözüldü %hmenu.nick $+ , lütfen bekleme yapmayınız.
    unset %hmenu.nick | set %hmenu.pause off 
  }
}
on *:quit:if $nick == %hmenu.nick { unset %hmenu.nick | set %hmenu.pause off }
on *:nick:if $nick == %hmenu.nick { set %hmenu.nick $newnick }
on *:part:#help:if $nick == %hmenu.nick { unset %hmenu.nick | set %hmenu.pause off }
on @*:join:#help:{
  if $read(nicks.txt,w,$nick) { return }
  if (%hmenu.uyar == on) { echo -ta $nick nicki #help kanalında yardım bekliyor. }
  if (%hmenu.pause != on) { mode # +v $nick }
}
dialog hnickler {
  title "Harici nickler"
  size -1 -1 89 77
  option dbu
  text "#Help kanalına girişlerde +v verilmesini istemediğiniz nickleri buraya yazınız. Bu nickler op/halfop veya server yöneticileri olabilir.", 1, 2 3 86 27, center
  box "", 2, 1 0 88 30
  combo 3, 2 32 64 45, size sort
  button "Ekle", 4, 67 32 20 10, flat disable
  button "Sil", 5, 67 42 20 10, flat disable
  button "Kapat", 6, 67 65 20 10, flat ok
  box "", 7, 1 27 88 50
}
alias hnickler { if !$dialog(hnickler) { dialog -ma hnickler hnickler } }
on *:dialog:hnickler:*:*:{
  if $devent == INIT {
    loadbuf -o $dname 3 nicks.txt
  }
  if $devent == SCLICK {
    if $did == 3 { did -e $dname 4,5 }
    if $did == 4 {
      if !$did(3).text { echo 4 -a :: Hata; Eklemek için nick yazmalısınız. | return }
      elseif $read(nicks.txt,w,$did(3).text) { echo 4 -a :: Hata; Bu nick zaten harici nickler listesinde. }
      else { write nicks.txt $did(3).text | did -a $dname 3 $did(3).text }
    }
    if $did == 5 {
      if !$did(3).text { echo 4 -a :: Hata; Silmek için nick seçmelisiniz. | return }
      elseif !$read(nicks.txt,w,$did(3).text) { echo 4 -a :: Hata; Bu nick harici nickler listesinde zaten yok. }
      else { write $+(-dw,",$did(3).text,") nicks.txt | did -d $dname 3 $did(3).sel }
  } }
  if $devent == EDIT { did -e $dname 4 }
}
alias hmenu { if !$dialog(hmenu) { dialog -ma hmenu hmenu } }
dialog hmenu {
  title "Helper Menü"
  size -1 -1 70 53
  option dbu
  check "Helper Menüyü Aç", 1, 3 6 64 9, push
  check "Otomatik voice aç", 2, 3 18 64 10, push
  check "#Help girişlerinde uyar", 3, 3 28 64 10, push
  box "", 4, 1 13 68 27
  box "", 5, 1 1 68 16
  button "Harici nickler", 6, 3 41 36 10, flat
  button "Kapat", 7, 40 41 27 10, default flat ok
  box "", 8, 1 36 68 17
}
on *:dialog:hmenu:*:*:{
  if $devent == INIT {
    if %hmenu != on { did -b $dname 2,3 } | elseif %hmenu == on { did -c $dname 1 | did -ra $dname 1 Helper Menüyü kapa }
    if %hmenu.helpvoice == on { did -c $dname 2 }
    if %hmenu.uyar == on { did -c $dname 3 }
  }
  if $devent == SCLICK {
    if $did == 1 {
      set %hmenu $iif($did(1).state == 1,on,off)
      did $iif($did(1).state == 0,-b,-e) $dname 2,3
      if $did(1).state == 1 {
        if %hmenu.helpvoice == on { did -c $dname }
        if %hmenu.uyar == on { did -c $dname }
      }
      did -ra $dname 1 Helper Menüyü $iif($did(1).state == 0,Aç,Kapa)
    }
    if $did == 2 {
      set %hmenu.helpvoice $iif($did(2).state == 1,on,off)
      did -ra $dname 2 Otomatik voice $iif($did(2).state == 0,aç,kapa)
    }
    if $did == 3 {
      set %hmenu.uyar $iif($did(3).state == 1,on,off)
      did -ra $dname 3 Help girişlerinde $iif($did(3).state == 1,uyarma,uyar)
    }
    if $did == 6 { hnickler }
  }
}
menu * {
  Helper Menu:hmenu 
}